home *** CD-ROM | disk | FTP | other *** search
/ SGI Freeware 1999 August / SGI Freeware 1999 August.iso / dist / fw_xemacs.idb / usr / freeware / lib / xemacs-20.4 / lisp / ediff / ediff-ptch.el.z / ediff-ptch.el
Encoding:
Text File  |  1998-05-21  |  25.1 KB  |  711 lines
  1. ;;; ediff-ptch.el --- Ediff's  patch support
  2.  
  3. ;; Copyright (C) 1996, 1997 Free Software Foundation, Inc.
  4.  
  5. ;; Author: Michael Kifer <kifer@cs.sunysb.edu>
  6.  
  7. ;; This file is part of GNU Emacs.
  8.  
  9. ;; GNU Emacs is free software; you can redistribute it and/or modify
  10. ;; it under the terms of the GNU General Public License as published by
  11. ;; the Free Software Foundation; either version 2, or (at your option)
  12. ;; any later version.
  13.  
  14. ;; GNU Emacs is distributed in the hope that it will be useful,
  15. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17. ;; GNU General Public License for more details.
  18.  
  19. ;; You should have received a copy of the GNU General Public License
  20. ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21. ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22. ;; Boston, MA 02111-1307, USA.
  23.  
  24.  
  25. ;;; Code:
  26.      
  27. (provide 'ediff-ptch)
  28.  
  29. (defgroup ediff-ptch nil
  30.   "Ediff patch support"
  31.   :tag "Patch"
  32.   :prefix "ediff-"
  33.   :group 'ediff)
  34.  
  35. ;; compiler pacifier
  36. (defvar ediff-window-A)
  37. (defvar ediff-window-B)
  38. (defvar ediff-window-C)
  39. (defvar ediff-use-last-dir)
  40. (defvar ediff-shell)
  41.  
  42. (eval-when-compile
  43.   (let ((load-path (cons (expand-file-name ".") load-path)))
  44.     (or (featurep 'ediff-init)
  45.     (load "ediff-init.el" nil nil 'nosuffix))
  46.     (or (featurep 'ediff)
  47.     (load "ediff.el" nil nil 'nosuffix))
  48.     ))
  49. ;; end pacifier
  50.  
  51. (require 'ediff-init)
  52.  
  53. (defcustom ediff-patch-program  "patch"
  54.   "*Name of the program that applies patches.
  55. It is recommended to use GNU-compatible versions."
  56.   :type 'string
  57.   :group 'ediff-ptch)
  58. (defcustom ediff-patch-options "-f"
  59.   "*Options to pass to ediff-patch-program.
  60.  
  61. Note: the `-b' option should be specified in `ediff-backup-specs'.
  62.  
  63. It is recommended to pass the `-f' option to the patch program, so it won't ask
  64. questions. However, some implementations don't accept this option, in which
  65. case the default value for this variable should be changed."
  66.   :type 'string
  67.   :group 'ediff-ptch)
  68.  
  69. (defvar ediff-last-dir-patch nil
  70.   "Last directory used by an Ediff command for file to patch.")
  71.  
  72. ;; the default backup extension
  73. (defconst ediff-default-backup-extension
  74.   (if (memq system-type '(vax-vms axp-vms emx ms-dos))
  75.       "_orig" ".orig"))
  76.   
  77.  
  78. (defcustom ediff-backup-extension ediff-default-backup-extension
  79.   "Backup extension used by the patch program.
  80. See also `ediff-backup-specs'."
  81.   :type 'string
  82.   :group 'ediff-ptch)
  83.  
  84. (defun ediff-test-patch-utility ()
  85.   (cond ((zerop (call-process ediff-patch-program nil nil nil "-z." "-b"))
  86.      ;; GNU `patch' v. >= 2.2
  87.      'gnu)
  88.     ((zerop (call-process ediff-patch-program nil nil nil "-b"))
  89.      'posix)
  90.     (t 'traditional)))
  91.  
  92. (defcustom ediff-backup-specs 
  93.   (let ((type (ediff-test-patch-utility)))
  94.     (cond ((eq type 'gnu)
  95.        ;; GNU `patch' v. >= 2.2
  96.        (format "-z%s -b" ediff-backup-extension))
  97.       ((eq type 'posix)
  98.        ;; POSIX `patch' -- ediff-backup-extension must be ".orig"
  99.        (setq ediff-backup-extension ediff-default-backup-extension)
  100.        "-b")
  101.       (t
  102.        ;; traditional `patch'
  103.        (format "-b %s" ediff-backup-extension))))
  104.   "*Backup directives to pass to the patch program.
  105. Ediff requires that the old version of the file \(before applying the patch\)
  106. be saved in a file named `the-patch-file.extension'. Usually `extension' is
  107. `.orig', but this can be changed by the user and may depend on the system.
  108. Therefore, Ediff needs to know the backup extension used by the patch program.
  109.  
  110. Some versions of the patch program let you specify `-b backup-extension'.
  111. Other versions only permit `-b', which assumes the extension `.orig'
  112. \(in which case ediff-backup-extension MUST be also `.orig'\). The latest
  113. versions of GNU patch require `-b -z backup-extension'.
  114.  
  115. Note that both `ediff-backup-extension' and `ediff-backup-specs'
  116. must be set properly. If your patch program takes the option `-b',
  117. but not `-b extension', the variable `ediff-backup-extension' must
  118. still be set so Ediff will know which extension to use.
  119.  
  120. Ediff tries to guess the appropriate value for this variables. It is believed
  121. to be working for `traditional' patch, all versions of GNU patch, and for POSIX
  122. patch. So, don't change these variables, unless the default doesn't work."
  123.   :type 'string
  124.   :group 'ediff-ptch)
  125.  
  126.  
  127. (defcustom ediff-patch-default-directory nil
  128.   "*Default directory to look for patches."
  129.   :type '(choice (const nil) string)
  130.   :group 'ediff-ptch)
  131.  
  132. (defcustom ediff-context-diff-label-regexp
  133.   (concat "\\("     ; context diff 2-liner
  134.       "^\\*\\*\\* \\([^ \t]+\\)[^*]+[\t ]*\n--- \\([^ \t]+\\)"
  135.       "\\|"     ; GNU unified format diff 2-liner
  136.       "^--- \\([^ \t]+\\)[\t ]+.*\n\\+\\+\\+ \\([^ \t]+\\)"
  137.       "\\)")
  138.   "*Regexp matching filename 2-liners at the start of each context diff.
  139. You probably don't want to change that, unless you are using an obscure patch
  140. program."
  141.   :type 'regexp
  142.   :group 'ediff-ptch)
  143.  
  144. ;; The buffer of the patch file. Local to control buffer.
  145. (ediff-defvar-local ediff-patchbufer nil "")
  146.  
  147. ;; The buffer where patch displays its diagnostics.
  148. (ediff-defvar-local ediff-patch-diagnostics nil "")
  149.  
  150. ;; Map of patch buffer. Has the form:
  151. ;;    ((filename1 marker1 marker2) (filename2 marker1 marker2) ...)
  152. ;; where filenames are files to which patch would have applied the patch;
  153. ;; marker1 delimits the beginning of the corresponding patch and marker2 does
  154. ;; it for the end.
  155. (ediff-defvar-local ediff-patch-map nil "")
  156.  
  157. ;; strip prefix from filename
  158. ;; returns /dev/null, if can't strip prefix
  159. (defsubst ediff-file-name-sans-prefix (filename prefix)
  160.   (save-match-data
  161.     (if (string-match (concat "^" prefix) filename)
  162.     (substring filename (match-end 0))
  163.       (concat "/null/" filename))))
  164.  
  165.  
  166.  
  167. ;; no longer used
  168. ;; return the number of matches of regexp in buf starting from the beginning
  169. (defun ediff-count-matches (regexp buf)
  170.   (ediff-with-current-buffer buf
  171.     (let ((count 0) opoint)
  172.       (save-excursion
  173.     (goto-char (point-min))
  174.     (while (and (not (eobp))
  175.             (progn (setq opoint (point))
  176.                (re-search-forward regexp nil t)))
  177.       (if (= opoint (point))
  178.           (forward-char 1)
  179.         (setq count (1+ count)))))
  180.       count)))
  181.  
  182. ;; Scan BUF (which is supposed to contain a patch) and make a list of the form 
  183. ;;    ((filename1 marker1 marker2) (filename2 marker1 marker2) ...)
  184. ;; where filenames are files to which patch would have applied the patch;
  185. ;; marker1 delimits the beginning of the corresponding patch and marker2 does
  186. ;; it for the end. This list is then assigned to ediff-patch-map.
  187. ;; Returns the number of elements in the list ediff-patch-map
  188. (defun ediff-map-patch-buffer (buf)
  189.   (ediff-with-current-buffer buf
  190.     (let ((count 0)
  191.       (mark1 (move-marker (make-marker) (point-min)))
  192.       (mark1-end (point-min))
  193.       (possible-file-names '("/dev/null" . "/dev/null"))
  194.       mark2-end mark2 filenames
  195.       beg1 beg2 end1 end2
  196.       patch-map opoint)
  197.       (save-excursion
  198.     (goto-char (point-min))
  199.     (setq opoint (point))
  200.     (while (and (not (eobp))
  201.             (re-search-forward ediff-context-diff-label-regexp nil t))
  202.       (if (= opoint (point))
  203.           (forward-char 1) ; ensure progress towards the end
  204.         (setq mark2 (move-marker (make-marker) (match-beginning 0))
  205.           mark2-end (match-end 0)
  206.           beg1 (or (match-beginning 2) (match-beginning 4))
  207.            end1 (or (match-end 2) (match-end 4))
  208.            beg2 (or (match-beginning 3) (match-beginning 5))
  209.            end2 (or (match-end 3) (match-end 5)))
  210.         ;; possible-file-names is holding the new file names until we
  211.         ;; insert the old file name in the patch map
  212.         ;; It is a pair (filename from 1st header line . fn from 2nd line)
  213.         (setq possible-file-names
  214.           (cons (if (and beg1 end1)
  215.                 (buffer-substring beg1 end1)
  216.               "/dev/null")
  217.             (if (and beg2 end2)
  218.                 (buffer-substring beg2 end2)
  219.               "/dev/null")))
  220.         ;; check for any `Index:' or `Prereq:' lines, but don't use them
  221.         (if (re-search-backward "^Index:" mark1-end 'noerror)
  222.         (move-marker mark2 (match-beginning 0)))
  223.         (if (re-search-backward "^Prereq:" mark1-end 'noerror)
  224.         (move-marker mark2 (match-beginning 0)))
  225.  
  226.         (goto-char mark2-end)
  227.         
  228.         (if filenames
  229.         (setq patch-map (cons (list filenames mark1 mark2) patch-map)))
  230.         (setq mark1 mark2
  231.           mark1-end mark2-end
  232.           filenames possible-file-names))
  233.       (setq opoint (point)
  234.         count (1+ count))))
  235.       (setq mark2 (point-max-marker)
  236.         patch-map (cons (list possible-file-names mark1 mark2) patch-map))
  237.       (setq ediff-patch-map (nreverse patch-map))
  238.       count)))
  239.  
  240. ;; Fix up the file names in the list using the argument FILENAME
  241. ;; Algorithm: find the first file's directory and cut it out from each file
  242. ;; name in the patch. Prepend the directory of FILENAME to each file in the
  243. ;; patch. In addition, the first file in the patch is replaced by FILENAME.
  244. ;; Each file is actually a file-pair of files found in the context diff header
  245. ;; In the end, for each pair, we select the shortest existing file.
  246. ;; Note: Ediff doesn't recognize multi-file patches that are separated
  247. ;; with the `Index:' line. It treats them as a single-file patch.
  248. ;;
  249. ;; Executes inside the patch buffer
  250. (defun ediff-fixup-patch-map (filename)
  251.   (setq filename (expand-file-name filename))
  252.   (let ((actual-dir (if (file-directory-p filename)
  253.             ;; directory part of filename
  254.             (file-name-as-directory filename)
  255.               (file-name-directory filename)))
  256.     ;; directory part of the first file in the patch
  257.     (base-dir1 (file-name-directory (car (car (car ediff-patch-map)))))
  258.     (base-dir2 (file-name-directory (cdr (car (car ediff-patch-map)))))
  259.     )
  260.  
  261.     ;; chop off base-dirs
  262.     (mapcar (function (lambda (triple)
  263.             (or (string= (car (car triple)) "/dev/null")
  264.                 (setcar (car triple)
  265.                     (ediff-file-name-sans-prefix
  266.                      (car (car triple)) base-dir1)))
  267.             (or (string= (cdr (car triple)) "/dev/null")
  268.                 (setcdr (car triple)
  269.                     (ediff-file-name-sans-prefix
  270.                      (cdr (car triple)) base-dir2)))
  271.             ))
  272.         ediff-patch-map)
  273.  
  274.     ;; take the given file name into account
  275.     (or (file-directory-p filename)
  276.     (string= "/dev/null" filename)
  277.     (progn
  278.       (setcar (car ediff-patch-map)
  279.           (cons (file-name-nondirectory filename)
  280.             (file-name-nondirectory filename)))))
  281.  
  282.     ;; prepend actual-dir
  283.     (mapcar (function (lambda (triple)
  284.              (if (and (string-match "^/null/" (car (car triple)))
  285.                   (string-match "^/null/" (cdr (car triple))))
  286.                  ;; couldn't strip base-dir1 and base-dir2
  287.                  ;; hence, something wrong
  288.                  (progn
  289.                    (with-output-to-temp-buffer ediff-msg-buffer
  290.                  (princ
  291.                   (format "
  292. The patch file contains a context diff for
  293.     %s
  294.     %s
  295. However, Ediff cannot infer the name of the actual file
  296. to be patched on your system. If you know the correct file name,
  297. please enter it now.
  298.  
  299. If you don't know and still would like to apply patches to
  300. other files, enter /dev/null
  301. "
  302.                       (substring (car (car triple)) 6)
  303.                       (substring (cdr (car triple)) 6))))
  304.                    (let ((directory t)
  305.                      user-file)
  306.                  (while directory
  307.                    (setq user-file
  308.                      (read-file-name
  309.                       "Please enter file name: "
  310.                       actual-dir actual-dir t))
  311.                    (if (not (file-directory-p user-file))
  312.                        (setq directory nil)
  313.                      (setq directory t)
  314.                      (beep)
  315.                      (message "%s is a directory" user-file)
  316.                      (sit-for 2)))
  317.                  (setcar triple (cons user-file user-file))))
  318.                (setcar (car triple)
  319.                    (expand-file-name 
  320.                     (concat actual-dir (car (car triple)))))
  321.                (setcdr (car triple)
  322.                    (expand-file-name 
  323.                     (concat actual-dir (cdr (car triple))))))
  324.              ))
  325.         ediff-patch-map)
  326.     ;; check for the shorter existing file in each pair and discard the other
  327.     ;; one
  328.     (mapcar (function (lambda (triple)
  329.             (let* ((file1 (car (car triple)))
  330.                    (file2 (cdr (car triple)))
  331.                    (f1-exists (file-exists-p file1))
  332.                    (f2-exists (file-exists-p file2)))
  333.               (cond
  334.                ((and (< (length file2) (length file1))
  335.                  f2-exists)
  336.                 (setcar triple file2))
  337.                ((and (< (length file1) (length file2))
  338.                  f1-exists)
  339.                 (setcar triple file1))
  340.                ((and f1-exists f2-exists
  341.                  (string= file1 file2))
  342.                 (setcar triple file1))
  343.                ((and f1-exists f2-exists)
  344.                 (with-output-to-temp-buffer ediff-msg-buffer
  345.                   (princ (format "
  346. Ediff has inferred that
  347.     %s
  348.     %s
  349. are two possible targets for applying the patch.
  350. Both files seem to be plausible alternatives.
  351.  
  352. Please advice:
  353.     Type `y' to use %s as the target;
  354.     Type `n' to use %s as the target.
  355. "
  356.                          file1 file2 file2 file1)))
  357.                 (setcar triple
  358.                     (if (y-or-n-p (format "Use %s ? " file2))
  359.                     file2 file1)))
  360.                (f2-exists (setcar triple file2))
  361.                (f1-exists (setcar triple file1))
  362.                (t
  363.                 (with-output-to-temp-buffer ediff-msg-buffer
  364.                   (princ "\nEdiff has inferred that")
  365.                   (if (string= file1 file2)
  366.                   (princ (format "
  367.     %s
  368. is the target for this patch. However, this file does not exist."
  369.                          file1))
  370.                 (princ (format "
  371.     %s
  372.     %s
  373. are two possible targets for this patch. However, these files do not exist."
  374.                            file1 file2)))
  375.                   (princ "
  376. \nPlease enter an alternative patch target ...\n"))
  377.                 (let ((directory t)
  378.                   target)
  379.                   (while directory
  380.                 (setq target (read-file-name 
  381.                           "Please enter a patch target: "
  382.                           actual-dir actual-dir t))
  383.                 (if (not (file-directory-p target))
  384.                     (setq directory nil)
  385.                   (beep)
  386.                   (message "%s is a directory" target)
  387.                   (sit-for 2)))
  388.                   (setcar triple target)))))))
  389.         ediff-patch-map)
  390.     ))
  391.  
  392. (defun ediff-show-patch-diagnostics ()
  393.   (interactive)
  394.   (cond ((window-live-p ediff-window-A)
  395.      (set-window-buffer ediff-window-A ediff-patch-diagnostics))
  396.     ((window-live-p ediff-window-B)
  397.      (set-window-buffer ediff-window-B ediff-patch-diagnostics))
  398.     (t (display-buffer ediff-patch-diagnostics 'not-this-window))))
  399.  
  400. (defun ediff-get-patch-buffer ()
  401.   "Obtain patch buffer.  If patch is already in a buffer---use it.
  402. Else, read patch file into a new buffer."
  403.   (let ((dir (cond (ediff-patch-default-directory) ; try patch default dir
  404.            (ediff-use-last-dir ediff-last-dir-patch)
  405.            (t default-directory)))
  406.     patch-buf)
  407.     (if (let ((last-nonmenu-event t) ; Emacs: don't use dialog box
  408.           last-command-event)    ; XEmacs: don't use dialog box
  409.       (y-or-n-p "Is the patch already in a buffer? "))
  410.     (setq patch-buf
  411.           (get-buffer
  412.            (read-buffer
  413.         "Which buffer contains the patch? "
  414.         (ediff-other-buffer
  415.          (if (eq (next-window (selected-window)) (selected-window))
  416.              ;; only one window in frame --- don't skip current buff
  417.              ""
  418.            ;; >1 window --- skip current buff, assuming this is the one
  419.            ;; to patch, not the one that has the patch
  420.            (current-buffer)))
  421.         'must-match)))
  422.       (setq patch-buf
  423.         (find-file-noselect
  424.          (read-file-name "Which file contains the patch? "
  425.                  dir nil 'must-match))))
  426.     
  427.     (ediff-with-current-buffer patch-buf
  428.       (goto-char (point-min))
  429.       (or (ediff-get-visible-buffer-window patch-buf)
  430.       (progn
  431.         (pop-to-buffer patch-buf 'other-window)
  432.         (select-window (previous-window)))))
  433.     (ediff-map-patch-buffer patch-buf)
  434.     patch-buf))
  435.  
  436. ;; Dispatch the right patch file function: regular or meta-level,
  437. ;; depending on how many patches are in the patch file.
  438. ;; At present, there is no support for meta-level patches.
  439. ;; Should return either the ctl buffer or the meta-buffer
  440. (defun ediff-dispatch-file-patching-job (patch-buf filename
  441.                            &optional startup-hooks)
  442.   (ediff-with-current-buffer patch-buf
  443.     ;; relativize names in the patch with respect to source-file
  444.     (ediff-fixup-patch-map filename)
  445.     (if (< (length ediff-patch-map) 2)
  446.     (ediff-patch-file-internal
  447.      patch-buf
  448.      (if (and (not (string-match "^/dev/null" (car (car ediff-patch-map))))
  449.           (> (length (car (car ediff-patch-map))) 1))
  450.          (car (car ediff-patch-map))
  451.        filename)
  452.      startup-hooks)
  453.       (ediff-multi-patch-internal patch-buf startup-hooks))
  454.     ))
  455.  
  456.  
  457. ;; When patching a buffer, never change the orig file. Instead, create a new
  458. ;; buffer, ***_patched, even if the buff visits a file.
  459. ;; Users who want to actually patch the buffer should use
  460. ;; ediff-patch-file, not ediff-patch-buffer.
  461. (defun ediff-patch-buffer-internal (patch-buf
  462.                     buf-to-patch-name
  463.                     &optional startup-hooks)
  464.   (let* ((buf-to-patch (get-buffer buf-to-patch-name))
  465.      (visited-file (if buf-to-patch (buffer-file-name  buf-to-patch)))
  466.      (buf-mod-status (buffer-modified-p buf-to-patch))
  467.      (multifile-patch-p (> (length (ediff-with-current-buffer patch-buf
  468.                      ediff-patch-map)) 1))
  469.      default-dir file-name ctl-buf)
  470.     (if multifile-patch-p
  471.     (error
  472.      "Can't apply multi-file patches to buffers that visit no files"))
  473.  
  474.     ;; create a temp file to patch
  475.     (ediff-with-current-buffer buf-to-patch
  476.       (setq default-dir default-directory)
  477.       (setq file-name (ediff-make-temp-file buf-to-patch))
  478.       ;; temporarily switch visited file name, if any
  479.       (set-visited-file-name file-name)
  480.       ;; don't create auto-save file, if buff was visiting a file
  481.       (or visited-file
  482.       (setq buffer-auto-save-file-name nil))
  483.       ;; don't confuse the user with a new bufname
  484.       (rename-buffer buf-to-patch-name)
  485.       (set-buffer-modified-p nil)
  486.       (set-visited-file-modtime) ; sync buffer and temp file
  487.       (setq default-directory default-dir)
  488.       )
  489.   
  490.     ;; dispatch a patch function
  491.     (setq ctl-buf (ediff-dispatch-file-patching-job
  492.            patch-buf file-name startup-hooks))
  493.     
  494.     (ediff-with-current-buffer ctl-buf
  495.       (delete-file (buffer-file-name ediff-buffer-A))
  496.       (delete-file (buffer-file-name ediff-buffer-B))
  497.       (ediff-with-current-buffer ediff-buffer-A
  498.     (if default-dir (setq default-directory default-dir))
  499.     (set-visited-file-name visited-file) ; visited-file might be nil
  500.     (rename-buffer buf-to-patch-name)
  501.     (set-buffer-modified-p buf-mod-status))
  502.       (ediff-with-current-buffer ediff-buffer-B
  503.     (setq buffer-auto-save-file-name nil) ; don't create auto-save file
  504.     (if default-dir (setq default-directory default-dir))
  505.     (set-visited-file-name nil)
  506.     (rename-buffer (ediff-unique-buffer-name 
  507.             (concat buf-to-patch-name "_patched") ""))
  508.     (set-buffer-modified-p t)))
  509.     ))
  510.  
  511.  
  512. ;; Traditional patch has weird return codes.
  513. ;; GNU and Posix return 1 if some hanks failed and 2 in case of trouble.
  514. ;; 0 is a good code in all cases.
  515. ;; We'll do the concervative thing.
  516. (defun ediff-patch-return-code-ok (code)
  517.   (eq code 0))
  518. ;;;  (if (eq (ediff-test-patch-utility) 'traditional)
  519. ;;;      (eq code 0)
  520. ;;;    (not (eq code 2))))
  521.  
  522. (defun ediff-patch-file-internal (patch-buf source-filename
  523.                         &optional startup-hooks)
  524.   (setq source-filename (expand-file-name source-filename))
  525.   
  526.   (let* ((shell-file-name ediff-shell)
  527.      (patch-diagnostics (get-buffer-create "*ediff patch diagnostics*"))
  528.      ;; ediff-find-file may use a temp file to do the patch
  529.      ;; so, we save source-filename and true-source-filename as a var
  530.      ;; that initially is source-filename but may be changed to a temp
  531.      ;; file for the purpose of patching.
  532.      (true-source-filename source-filename)
  533.      (target-filename source-filename)
  534.      target-buf buf-to-patch file-name-magic-p 
  535.      patch-return-code ctl-buf backup-style aux-wind)
  536.       
  537.     (if (string-match "V" ediff-patch-options)
  538.     (error
  539.      "Ediff doesn't take the -V option in `ediff-patch-options'--sorry"))
  540.                     
  541.     ;; Make a temp file, if source-filename has a magic file handler (or if
  542.     ;; it is handled via auto-mode-alist and similar magic).
  543.     ;; Check if there is a buffer visiting source-filename and if they are in
  544.     ;; sync; arrange for the deletion of temp file.
  545.     (ediff-find-file 'true-source-filename 'buf-to-patch
  546.              'ediff-last-dir-patch 'startup-hooks)
  547.  
  548.     ;; Check if source file name has triggered black magic, such as file name
  549.     ;; handlers or auto mode alist, and make a note of it.
  550.     ;; true-source-filename should be either the original name or a
  551.     ;; temporary file where we put the after-product of the file handler.
  552.     (setq file-name-magic-p (not (equal (file-truename true-source-filename)
  553.                     (file-truename source-filename))))
  554.     
  555.     ;; Checkout orig file, if necessary, so that the patched file 
  556.     ;; could be checked back in.
  557.     (ediff-maybe-checkout buf-to-patch)
  558.  
  559.     (ediff-with-current-buffer patch-diagnostics
  560.       (insert-buffer patch-buf)
  561.       (message "Applying patch ... ")
  562.       ;; fix environment for gnu patch, so it won't make numbered extensions
  563.       (setq backup-style (getenv "VERSION_CONTROL"))
  564.       (setenv "VERSION_CONTROL" nil)
  565.       (setq patch-return-code
  566.         (call-process-region
  567.          (point-min) (point-max)
  568.          shell-file-name
  569.          t   ; delete region (which contains the patch
  570.          t   ; insert output (patch diagnostics) in current buffer
  571.          nil ; don't redisplay
  572.          shell-command-switch   ; usually -c
  573.          (format "%s %s %s %s"
  574.              ediff-patch-program
  575.              ediff-patch-options
  576.              ediff-backup-specs
  577.              (expand-file-name true-source-filename))
  578.          ))
  579.  
  580.       ;; restore environment for gnu patch
  581.       (setenv "VERSION_CONTROL" backup-style))
  582.  
  583.     (message "Applying patch ... done")
  584.     (message "")
  585.  
  586.     (switch-to-buffer patch-diagnostics)
  587.     (sit-for 0) ; synchronize - let the user see diagnostics
  588.     
  589.     (or (and (ediff-patch-return-code-ok patch-return-code)
  590.          (file-exists-p
  591.           (concat true-source-filename ediff-backup-extension)))
  592.     (progn
  593.       (with-output-to-temp-buffer ediff-msg-buffer
  594.         (princ (format 
  595.             "Patch program has failed due to a bad patch file,
  596. it couldn't apply all hunks, OR
  597. it couldn't create the backup for the file being patched.
  598.  
  599. The former could be caused by a corrupt patch file or because the %S
  600. program doesn't understand the format of the patch file in use.
  601.  
  602. The second problem might be due to an incompatibility among these settings:
  603.     ediff-patch-program    = %S             ediff-patch-options    = %S
  604.     ediff-backup-extension = %S             ediff-backup-specs     = %S
  605.  
  606. See Ediff on-line manual for more details on these variables.
  607. In particular, check the documentation for `ediff-backup-specs'. 
  608.  
  609. In any of the above cases, Ediff doesn't compare files automatically.
  610. However, if the patch was applied partially and the backup file was created,
  611. you can still examine the changes via M-x ediff-files"
  612.                ediff-patch-program
  613.                ediff-patch-program
  614.                ediff-patch-options
  615.                ediff-backup-extension
  616.                ediff-backup-specs
  617.                )))
  618.       (beep 1)
  619.       (if (setq aux-wind (get-buffer-window ediff-msg-buffer))
  620.           (progn
  621.         (select-window aux-wind)
  622.         (goto-char (point-max))))
  623.       (switch-to-buffer-other-window patch-diagnostics)
  624.       (error "Patch appears to have failed")))
  625.     
  626.     ;; If black magic is involved, apply patch to a temp copy of the
  627.     ;; file. Otherwise, apply patch to the orig copy.  If patch is applied
  628.     ;; to temp copy, we name the result old-name_patched for local files
  629.     ;; and temp-copy_patched for remote files. The orig file name isn't
  630.     ;; changed, and the temp copy of the original is later deleted.
  631.     ;; Without magic, the original file is renamed (usually into
  632.     ;; old-name_orig) and the result of patching will have the same name as
  633.     ;; the original.
  634.     (if (not file-name-magic-p)
  635.     (ediff-with-current-buffer buf-to-patch
  636.       (set-visited-file-name
  637.        (concat source-filename ediff-backup-extension))
  638.       (set-buffer-modified-p nil))
  639.       
  640.       ;; Black magic in effect.
  641.       ;; If orig file was remote, put the patched file in the temp directory.
  642.       ;; If orig file is local, put the patched file in the directory of
  643.       ;; the orig file.
  644.       (setq target-filename
  645.         (concat
  646.          (if (ediff-file-remote-p (file-truename source-filename))
  647.          true-source-filename
  648.            source-filename)
  649.          "_patched"))
  650.       
  651.       (rename-file true-source-filename target-filename t)
  652.       
  653.       ;; arrange that the temp copy of orig will be deleted
  654.       (rename-file (concat true-source-filename ediff-backup-extension)
  655.            true-source-filename t))
  656.     
  657.     ;; make orig buffer read-only
  658.     (setq startup-hooks
  659.       (cons 'ediff-set-read-only-in-buf-A startup-hooks))
  660.     
  661.     ;; set up a buf for the patched file
  662.     (setq target-buf (find-file-noselect target-filename))
  663.     
  664.     (setq ctl-buf
  665.       (ediff-buffers-internal
  666.        buf-to-patch target-buf nil
  667.        startup-hooks 'epatch))
  668.     (ediff-with-current-buffer ctl-buf
  669.       (setq ediff-patchbufer patch-buf
  670.         ediff-patch-diagnostics patch-diagnostics))
  671.   
  672.     (bury-buffer patch-diagnostics)
  673.     (message "Type `P', if you need to see patch diagnostics")
  674.     ctl-buf))
  675.  
  676. (defun ediff-multi-patch-internal (patch-buf &optional startup-hooks)
  677.   (let (meta-buf)
  678.     (setq startup-hooks
  679.       ;; this sets various vars in the meta buffer inside
  680.       ;; ediff-prepare-meta-buffer
  681.       (cons (` (lambda ()
  682.              ;; tell what to do if the user clicks on a session record
  683.              (setq ediff-session-action-function
  684.                'ediff-patch-file-form-meta
  685.                ediff-meta-patchbufer patch-buf)
  686.              ))
  687.         startup-hooks))
  688.     (setq meta-buf (ediff-prepare-meta-buffer 
  689.             'ediff-filegroup-action
  690.             (ediff-with-current-buffer patch-buf
  691.               ;; nil replaces a regular expression
  692.               (cons (list nil (format "%S" patch-buf))
  693.                 ediff-patch-map))
  694.             "*Ediff Session Group Panel"
  695.             'ediff-redraw-directory-group-buffer
  696.             'ediff-multifile-patch
  697.             startup-hooks))
  698.     (ediff-show-meta-buffer meta-buf)
  699.     ))
  700.  
  701.   
  702.       
  703.  
  704. ;;; Local Variables:
  705. ;;; eval: (put 'ediff-defvar-local 'lisp-indent-hook 'defun)
  706. ;;; eval: (put 'ediff-with-current-buffer 'lisp-indent-hook 1)
  707. ;;; eval: (put 'ediff-with-current-buffer 'edebug-form-spec '(form body))
  708. ;;; End:
  709.  
  710. ;;; ediff-ptch.el ends here
  711.